We're going to come at continuations from three different directions, and each time we're going to end up at the same place: a particular monad, which we'll call the Continuation monad.

Rethinking the List monad

To construct a monad, the key element is to settle on how to implement its type, and the monad more or less naturally follows from that. We'll remind you of some examples of how monads follow from their types in a moment. This will involve some review of familiar material, but it's worth doing for two reasons: it will set up a pattern for the new discussion further below, and it will tie together some previously unconnected elements of the course (more specifically, version 3 lists and monads).

For instance, take the Reader monad. Once we decide to define its type as:

type 'a reader = env -> 'a

then the choice of unit and bind is natural:

let r_unit (a : 'a) : 'a reader = fun (e : env) -> a

The reason this is a fairly natural choice is that because the type of an 'a reader is env -> 'a (by definition), the type of the r_unit function is 'a -> env -> 'a, which is an instance of the type of the K combinator. So it makes sense that K is the unit for the Reader monad.

Since the type of the bind operator is required to be

r_bind : 'a reader -> ('a -> 'b reader) -> 'b reader

We can reason our way to the traditional reader bind function as follows. We start by declaring the types determined by the definition of a bind operation:

let r_bind (u : 'a reader) (f : 'a -> 'b reader) : 'b reader = ...

Now we have to open up the u box and get out the 'a object in order to feed it to f. Since u is a function from environments to objects of type 'a, the way we open a box in this monad is by applying it to an environment:

... f (u e) ...

This subexpression types to 'b reader, which is good. The only problem is that we made use of an environment e that we didn't already have, so we must abstract over that variable to balance the books:

fun e -> f (u e) ...

[To preview the discussion of the Curry-Howard correspondence, what we're doing here is constructing an intuitionistic proof of the type, and using the Curry-Howard labeling of the proof as our bind term.]

This types to env -> 'b reader, but we want to end up with env -> 'b. Once again, the easiest way to turn a 'b reader into a 'b is to apply it to an environment. So we end up as follows:

r_bind (u : 'a reader) (f : 'a -> 'b reader) : 'b reader =
    fun e -> f (u e) e

And we're done. This gives us a bind function of the right type. We can then check whether, in combination with the unit function we chose, it satisfies the monad laws, and behaves in the way we intend. And it does.

[The bind we cite here is a condensed version of the careful let a = u e in ... constructions we provided in earlier lectures. We use the condensed version here in order to emphasize similarities of structure across monads.]

The State monad is similar. Once we've decided to use the following type constructor:

type 'a state = store -> ('a, store)

Then our unit is naturally:

let s_unit (a : 'a) : 'a state = fun (s : store) -> (a, s)

And we can reason our way to the bind function in a way similar to the reasoning given above. First, we need to apply f to the contents of the u box:

let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state =
    ... f (...) ...

But unlocking the u box is a little more complicated. As before, we need to posit a store s that we can apply u to. Once we do so, however, we won't have an 'a; we'll have a pair whose first element is an 'a. So we have to unpack the pair:

... let (a, s') = u s in ... f a ...

Abstracting over the s and adjusting the types gives the result:

let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state =
    fun (s : store) -> let (a, s') = u s in f a s'

The Option/Maybe monad doesn't follow the same pattern so closely, so we won't pause to explore it here, though conceptually its unit and bind follow just as naturally from its type constructor.

Our other familiar monad is the List monad, which we were told looks like this:

(* type 'a list = ['a];; *)
l_unit (a : 'a) = [a];;
l_bind u f = List.concat (List.map f u);;

Thinking through the List monad will take a little time, but doing so will provide a connection with continuations.

Recall that List.map takes a function and a list and returns the result of applying the function to the elements of the list:

List.map (fun i -> [i; i+1]) [1; 2] ~~> [[1; 2]; [2; 3]]

and List.concat takes a list of lists and erases one level of embedded list boundaries:

List.concat [[1; 2]; [2; 3]] ~~> [1; 2; 2; 3]

And sure enough,

l_bind [1; 2] (fun i -> [i; i+1]) ~~> [1; 2; 2; 3]

Now, why this unit, and why this bind? Well, ideally a unit should not throw away information, so we can rule out fun x -> [] as an ideal unit. And units should not add more information than required, so there's no obvious reason to prefer fun x -> [x; x]. In other words, fun x -> [x] is a reasonable choice for a unit.

As for bind, an 'a list monadic object contains a lot of objects of type 'a, and we want to make use of each of them (rather than arbitrarily throwing some of them away). The only thing we know for sure we can do with an object of type 'a is apply the function of type 'a -> 'b list to them. Once we've done so, we have a collection of lists, one for each of the 'a's. One possibility is that we could gather them all up in a list, so that bind' [1; 2] (fun i -> [i; i]) ~~> [[1; 1]; [2; 2]]. But that restricts the object returned by the second argument of bind to always be of type ('something list) list. We can eliminate that restriction by flattening the list of lists into a single list: this is just List.concat applied to the output of List.map. So there is some logic to the choice of unit and bind for the List monad.

Yet we can still desire to go deeper, and see if the appropriate bind behavior emerges from the types, as it did for the previously considered monads. But we can't do that if we leave the list type as a primitive OCaml type. However, we know several ways of implementing lists using just functions. In what follows, we're going to use version 3 lists, the right fold implementation (though it's important and intriguing to wonder how things would change if we used some other strategy for implementing lists). These were the lists that made lists look like Church numerals with extra bits embedded in them:

empty list:                fun f z -> z
list with one element:     fun f z -> f 1 z
list with two elements:    fun f z -> f 2 (f 1 z)
list with three elements:  fun f z -> f 3 (f 2 (f 1 z))

and so on. To save time, we'll let the OCaml interpreter infer the principle types of these functions (rather than inferring what the types should be ourselves):

# fun f z -> z;;
- : 'a -> 'b -> 'b = <fun>
# fun f z -> f 1 z;;
- : (int -> 'a -> 'b) -> 'a -> 'b = <fun>
# fun f z -> f 2 (f 1 z);;
- : (int -> 'a -> 'a) -> 'a -> 'a = <fun>
# fun f z -> f 3 (f 2 (f 1 z))
- : (int -> 'a -> 'a) -> 'a -> 'a = <fun>

We can see what the consistent, general principle types are at the end, so we can stop. These types should remind you of the simply-typed lambda calculus types for Church numerals ((o -> o) -> o -> o) with one extra type thrown in, the type of the element at the head of the list (in this case, an int).

So here's our type constructor for our hand-rolled lists:

type 'b list' = (int -> 'b -> 'b) -> 'b -> 'b

Generalizing to lists that contain any kind of element (not just ints), we have

type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b

So an ('a, 'b) list' is a list containing elements of type 'a, where 'b is the type of some part of the plumbing. This is more general than an ordinary OCaml list, but we'll see how to map them into OCaml lists soon. We don't need to fully grasp the role of the 'bs in order to proceed to build a monad:

l'_unit (a : 'a) : ('a, 'b) list = fun a -> fun k z -> k a z

Take an 'a and return its v3-style singleton. No problem. Arriving at bind is a little more complicated, but exactly the same principles apply, you just have to be careful and systematic about it.

l'_bind (u : ('a, 'b) list') (f : 'a -> ('c, 'd) list') : ('c, 'd) list'  = ...

Unpacking the types gives:

l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b)
        (f : 'a -> ('c -> 'd -> 'd) -> 'd -> 'd)
           : ('c -> 'd -> 'd) -> 'd -> 'd = ...

Perhaps a bit intimidating. But it's a rookie mistake to quail before complicated types. You should be no more intimidated by complex types than by a linguistic tree with deeply embedded branches: complex structure created by repeated application of simple rules.

[This would be a good time to try to reason your way to your own term having the type just specified. Doing so (or attempting to do so) will make the next paragraph much easier to follow.]

As usual, we need to unpack the u box. Examine the type of u. This time, u will only deliver up its contents if we give u an argument that is a function expecting an 'a and a 'b. u will fold that function over its type 'a members, and that's where we can get at the 'as we need. Thus:

... u (fun (a : 'a) (b : 'b) -> ... f a ... ) ...

In order for u to have the kind of argument it needs, the fun a b -> ... f a ... has to have type 'a -> 'b -> 'b; so the ... f a ... has to evaluate to a result of type 'b. The easiest way to do this is to collapse (or "unify") the types 'b and 'd, with the result that f a will have type ('c -> 'b -> 'b) -> 'b -> 'b. Let's postulate an argument k of type ('c -> 'b -> 'b) and supply it to f a:

... u (fun (a : 'a) (b : 'b) -> ... f a k ... ) ...

Now the function we're supplying to u also receives an argument b of type 'b, so we can supply that to f a k, getting a result of type 'b, as we need:

... u (fun (a : 'a) (b : 'b) -> f a k b) ...

Now, we've used a k that we pulled out of nowhere, so we need to abstract over it:

fun (k : 'c -> 'b -> 'b) -> u (fun (a : 'a) (b : 'b) -> f a k b)

This whole expression has type ('c -> 'b -> 'b) -> 'b -> 'b, which is exactly the type of a ('c, 'b) list'. So we can hypothesize that our bind is:

l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b)
        (f : 'a -> ('c -> 'b -> 'b) -> 'b -> 'b)
           : ('c -> 'b -> 'b) -> 'b -> 'b =
    fun k -> u (fun a b -> f a k b)

That is a function of the right type for our bind, but to check whether it works, we have to verify it (with the unit we chose) against the monad laws, and reason whether it will have the right behavior.

Here's a way to persuade yourself that it will have the right behavior. First, it will be handy to eta-expand our fun k -> u (fun a b -> f a k b) to:

fun k z -> u (fun a b -> f a k b) z

Now let's think about what this does. It's a wrapper around u. In order to behave as the list v which is the result of mapping f over each element of u, and then joining (concating) the results, this wrapper would have to accept arguments k and z and fold them in just the same way that v would. Will it?

Suppose we have a list' whose contents are [1; 2; 4; 8]---that is, our list' u will be fun f z -> f 1 (f 2 (f 4 (f 8 z))). Suppose we also have a function f that for each int we give it, gives back a list of the divisors of that int that are greater than 1. Intuitively, then, binding u to f should give us:

v =
List.concat (List.map f u) =
List.concat [[]; [2]; [2; 4]; [2; 4; 8]] =
[2; 2; 4; 2; 4; 8]

Or rather, it should give us a list' version of that, which takes a function k and value z as arguments, and returns the right fold of k and z over those elements. Does our formula

fun k z -> u (fun a b -> f a k b) z

do that? Well, for each element a in u, it applies f to that a, getting one of the lists:

[]        ; result of applying f to leftmost a
[2; 4]
[2; 4; 8] ; result of applying f to rightmost a

(or rather, their list' versions). Then it takes the accumulated result b of previous steps in the k,z-fold, and it folds k and b over the list generated by f a. The result of doing so is passed on to the next step of the k,z-fold as the new accumulated result b.

So if, for example, we let k be + and z be 0, then the computation would proceed:

0 ==>
right-fold + and 0 over [2; 4; 8] = 2+4+8+(0) ==>
right-fold + and 2+4+8+0 over [2; 4] = 2+4+(2+4+8+(0)) ==>
right-fold + and 2+4+2+4+8+0 over [2] = 2+(2+4+(2+4+8+(0))) ==>
right-fold + and 2+2+4+2+4+8+0 over [] = 2+(2+4+(2+4+8+(0)))

which indeed is the result of right-folding + and 0 over [2; 2; 4; 2; 4; 8]. If you trace through how this works, you should be able to persuade yourself that our formula:

fun k z -> u (fun a b -> f a k b) z

will deliver just the same folds, for arbitrary choices of k and z (with the right types), and arbitrary list's u and appropriately-typed fs, as

fun k z -> List.fold_right k v z =
fun k z -> List.fold_right k (List.concat (List.map f u)) z


For future reference, we might make two eta-reductions to our formula, so that we have instead:

let l'_bind = fun k -> u (fun a -> f a k);;

Let's make some more tests:

# l_bind [1; 2] (fun i -> [i; i+1]);;
- : int list = [1; 2; 2; 3]

# l'_bind (fun f z -> f 1 (f 2 z)) (fun i -> fun f z -> f i (f (i+1) z));;
- : (int -> '_a -> '_a) -> '_a -> '_a = <fun>

Sigh. OCaml won't show us our own list. So we have to choose an f and a z that will turn our hand-crafted lists into standard OCaml lists, so that they will print out.

# let cons h t = h :: t;;  (* OCaml is stupid about :: *)
# l'_bind (fun f z -> f 1 (f 2 z)) (fun i -> fun f z -> f i (f (i+1) z)) cons [];;
- : int list = [1; 2; 2; 3]

Ta da!

Montague's PTQ treatment of DPs as generalized quantifiers

We've hinted that Montague's treatment of DPs as generalized quantifiers embodies the spirit of continuations (see de Groote 2001, Barker 2002 for lengthy discussion). Let's see why.

First, we'll need a type constructor. As we've said, Montague replaced individual-denoting determiner phrases (with type e) with generalized quantifiers (with [extensional] type (e -> t) -> t. In particular, the denotation of a proper name like John, which might originally denote a object j of type e, came to denote a generalized quantifier fun pred -> pred j of type (e -> t) -> t. Let's write a general function that will map individuals into their corresponding generalized quantifier:

gqize (a : e) = fun (p : e -> t) -> p a

This function is what Partee 1987 calls LIFT, which is not an unreasonable name. But we will avoid her term here, since that word has been used to refer to other functions in our discussion.

This function wraps up an individual in a box. That is to say, we are in the presence of a monad. The type constructor, the unit and the bind follow naturally. We've done this enough times that we won't belabor the construction of the bind function. The derivation is highly similar to the List monad just given:

type 'a continuation = ('a -> 'b) -> 'b
let c_unit (a : 'a) = fun (p : 'a -> 'b) -> p a
let c_bind (u : ('a -> 'b) -> 'b) (f : 'a -> ('c -> 'd) -> 'd) : ('c -> 'd) -> 'd =
    fun (k : 'a -> 'b) -> u (fun (a : 'a) -> f a k)

Note that c_unit is exactly the gqize function that Montague used to lift individuals into generalized quantifiers.

That last bit in c_bind looks familiar---we just saw something like it in the List monad. How similar is it to the List monad? Let's examine the type constructor and the terms from the list monad derived above:

type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b;;
    (* that is of the form ('a -> 'r) -> 'r, where 'r = 'b -> 'b *)
let l'_unit a = fun k z -> k a z;;

This can be eta-reduced to:

let l'_unit a = fun k -> k a


let l'_bind u f =
    (* we mentioned three versions of this, the eta-expanded: *)
    fun k z -> u (fun a b -> f a k b) z
    (* an intermediate version, and the fully eta-reduced: *)
    fun k -> u (fun a -> f a k)

Consider the most eta-reduced versions of l'_unit and l'_bind. They're the same as the unit and bind for the Montague Continuation monad! In other words, the behavior of our v3-List monad and the behavior of the continuations monad are parallel in a deep sense.

Have we really discovered that lists are secretly continuations? Or have we merely found a way of simulating lists using list continuations? Well, strictly speaking, what we have done is shown that one particular implementation of lists---the right fold implementation---gives rise to a Continuation monad fairly naturally, and that this monad can reproduce the behavior of the standard list monad. But what about other list implementations? Do they give rise to monads that can be understood in terms of continuations?